resource "proxmox_vm_qemu" "vm1" {
  name        = var.vm1_name
  target_node = var.pm_target_node
  clone       = var.vm1_template_name
  os_type     = "cloud-init"
  cicustom    = "vendor=local:snippets/setup-vm.yml"
  ciupgrade   = true
  ciuser      = var.ciuser
  sshkeys     = var.ssh_keys
  onboot      = false
  protection  = false
  vm_state    = var.vm1_state
  agent       = 1
  tags        = "terraform"
  description = <<EOF
Managed by Terraform.<br>
<br>Telepített szoftverek:
<li>qemu-guest-agent</li>
<li>mc</li>
<br>Készítette: <i>Márkus Sándor</i>
<br><a href="https://git.msandor.hu/demo/terraform" target="_blank">Telepítési útmutató, terraform fájlok</a>
<pre>SSH: ${var.ciuser}@${var.vm1_ip}</pre>
Deployed: ${formatdate("YYYY.MM.DD. hh:mm:ss ZZZ", timestamp())}
<br>FQDN: ${var.vm1_name}.${var.searchdomain}
EOF

  serial {
    id   = 0
    type = "socket"
  }

  cpu {
      cores = var.vm1_cores
      sockets = 1
      type = "host"
  }

  memory      = var.vm1_memory
  balloon     = 0
  boot        = "order=scsi0"
  bootdisk    = "scsi0"
  scsihw      = var.vm1_controller

  ipconfig0    = "ip=${var.vm1_ip}/${var.netmask},gw=${var.gateway}"
  skip_ipv6    = true
  nameserver   = var.nameserver
  searchdomain = var.searchdomain
  network {
      id = 0
      model = var.vm1_net_model
      bridge = var.vm1_net_bridge
  }

  disks {
    ide {
      ide0 {
        cloudinit {
          storage = "local"
        }
      }
    }
    scsi {
      scsi0 {
        disk {
          size         = var.vm1_disk_size
          cache        = "none"
          storage      = var.vm1_disk_storage
          iothread     = true
          discard      = false
        }
      }
      scsi1 {
        disk {
          size         = var.vm1_swap_size
          cache        = "none"
          storage      = var.vm1_disk_storage
          iothread     = true
          discard      = false
        }
      }
    }
  }

  lifecycle {
    ignore_changes = [network,description,bootdisk]
  }
}